Relay-Version: version B 2.10 5/3/83; site utzoo.UUCP
Posting-Version: version B 2.10.1 6/24/83 (MC830919); site mcvax.UUCP
Path: utzoo!linus!decvax!mcvax!aeb
From: aeb@mcvax.UUCP (Andries Brouwer)
Newsgroups: net.lang
Subject: Re: PRINT "Merry Christmas"
Message-ID: <5498@mcvax.UUCP>
Date: Thu, 17-Nov-83 19:40:02 EST
Article-I.D.: mcvax.5498
Posted: Thu Nov 17 19:40:02 1983
Date-Received: Sat, 12-Nov-83 13:07:51 EST
References: <397@aplvax.UUCP> <512@ariel.UUCP>
Organization: Math.Centre, Amsterdam
Lines: 49

/PRINT "MERRY CHRISTMAS" 15 TIMES (IN PAL: PDP8 ASSEMBLER)
START,	JMS	PRTXT
	"MERRY CHRISTMAS"
	ISZ	CNT
	JMP	START
	HLT

CNT,	-17

PRTXT,	0
FIRSTH,	CLA CLL CMA RAL	/CONSTRUCT -2
	DCA	HALF
	TAD I	PRTXT
	RTR
	RTR
	RTR
	JMP	.+3
OTHERH,	TAD I	PRTXT
	ISZ	PRTXT
	AND	(77
	SZA
	JMP	PRMORE
	TAD	(215
	JMS	TYPE
	TAD	(212
	JMS	TYPE
	JMP I	PRTXT	/MIGHT JUMP INTO HARMLESS DATA
PRMORE,	CLL
	TAD	(7740
	SNL
	TAD	(100
	TAD	(240	/COMPUTE ASCII CODE (NO PARITY)
	JMS	TYPE
	ISZ	HALF
	JMP	OTHERH
	JMP	FIRSTH

HALF,	-2

TYPE,	0
	TLS
	TSF
	JMP	.-1
	CLA
	JMP I	TYPE

$$$$$
-- 
      Andries Brouwer -- Math. Centr., Amsterdam -- {philabs,decvax}!mcvax!aeb