Relay-Version: version B 2.10 5/3/83; site utzoo.UUCP
Posting-Version: version B 2.10.1 6/24/83; site eneevax.UUCP
Path: utzoo!linus!philabs!cmcl2!seismo!umcp-cs!eneevax!balon
From: balon@eneevax.UUCP (Kevin G. Balon)
Newsgroups: net.micro.apple
Subject: Re: Double Hi-Resolution Graphics on IIe (Information Request)
Message-ID: <476@eneevax.UUCP>
Date: Thu, 9-Jan-86 22:29:22 EST
Article-I.D.: eneevax.476
Posted: Thu Jan  9 22:29:22 1986
Date-Received: Sat, 11-Jan-86 06:16:01 EST
References: <771@alberta.UUCP>, <2b32a187.7005@apollo.uucp>
Organization: U of Maryland, EE Dept., College Park, MD
Lines: 55


Double Hires is tricky to do.  The best software I have found to use it is 
BEAGLE GRAPHICS.  Also, refer to Apple's  'Extended 80-Column Text Card
Supplement' for the use of the soft-switches. Trying to do it in BASIC is 
much to slow.
BEAGLE GRAPHICS adds commands to BASIC to use in your own programs.
 
 
Nonetheless, here's a copy of an early program I wrote to use double hires
graphics on an Apple //e (Rev. B); it displays a sign wave:
I hope this helps out.
 
(By the way, I have no connection with BEAGLE SOFTWARE or APPLE; I am just an
 enthusiastic apple computer user)
 
************
 
 
100  GOSUB 4010: REM  Initialize
110  HCOLOR= 3
120  FOR X = 0 TO 559 STEP .25
140 :Y = 40 *  SIN (X / 10) + 80
160 : GOSUB 5010: REM  plot it
180  NEXT X
200  END 
3999  STOP 
4000  REM    ****************** INITIALIZATION *********************  
4010 D$ =  CHR$ (4)
4020  PRINT D$;"PR#3"
4025  HGR : REM  Clear half the hires screen also
4030  POKE  - 16300,0: REM Stay in page 1 graphics 
4040  POKE  - 16371,0: POKE  - 16384,0: REM   Turn on card and enble 80STORE
4050  POKE  - 16290,0: REM  Turn on AN3 (enable double res graphics)
4060  POKE  - 16297,0: POKE  - 16304,0: REM    Enable HIRES graphics and dispay it
4065  HCOLOR= 0: REM  This For/Next loop clear other half of screen
4070  FOR Y = 0 TO 191
4080  POKE  - 16383,0: POKE  - 16299,0: REM   Access Hires Page 1x in Auxiliary RAM
4090  HPLOT 0,Y TO 279,Y
4100  NEXT Y
4110  POKE  - 16384,0: REM  Access Hires Page 1 in main RAM
4120  RETURN 
4999  STOP 
5000  REM  *************** Double Res Plotting Subroutine *************
5010  IF X > 559 THEN  RETURN 
5020 COLUMN =  INT (X / 7)
5030 AUXFLAG = (COLUMN = 2 *  INT (COLUMN / 2))
5050 XREL = X - 7 * COLUMN
5060 FIRST = (COLUMN -  NOT AUX) * 3.5
5070 XPLT = FIRST + XREL
5080  POKE  - 16383,0: POKE AUXFLAG - 16300,0: REM  Enable 80STORE and select bank
5090  HPLOT XPLT,Y
5100  RETURN