Relay-Version: version B 2.10 5/3/83; site utzoo.UUCP
Path: utzoo!decvax!ucbvax!ulowell.cs.ulowell.edu!burati
From: burati@ulowell.cs.ulowell.edu.UUCP
Newsgroups: mod.computers.vax
Subject: Submission for mod-computers-vax
Message-ID: <8701052022.AA19646@ulowell.CS.ULOWELL.EDU>
Date: Mon, 5-Jan-87 15:22:36 EST
Article-I.D.: ulowell.8701052022.AA19646
Posted: Mon Jan  5 15:22:36 1987
Date-Received: Tue, 6-Jan-87 00:44:20 EST
Sender: daemon@ucbvax.BERKELEY.EDU
Organization: The ARPA Internet
Lines: 97
Approved: info-vax@sri-kl.arpa

Path: ulowell!burati
From: burati@ulowell.UUCP (Michael R. Burati)
Newsgroups: mod.computers.vax
Subject: Re: how to get around VMS mail problem
Message-ID: <916@ulowell.UUCP>
Date: 5 Jan 87 20:22:35 GMT
References: <8612310024.AA01143@ucbvax.Berkeley.EDU>
Reply-To: burati@ulowell.UUCP (Michael R. Burati)
Organization: University of Lowell
Lines: 87

	The command 'extract TT:' executed at the 'MAIL>' prompt
will take the current message and display it (without screen breaks)
on the current output device.  This seems to be what you need.

	As for the deleting of messages after a certain period of time,
that could be easily done from within a com file.  If I had the time,
or the need for that utility, I'd write it for you.  Basically, you'll
need to check each folder (found with the 'directory/folder' command) 
(or only specific folders, depending on what you need), then look at
the date (listed with the 'directory' command) of each message in the
folder.

Included below is a com file that I wrote a while back to list messages
in various mail folders.  Maybe it'll help you write what you need.

Michael Burati
University of Lowell
Comp Sci Dept

CSNET: burati@ulowell.csnet
UUCP:  ..{apollo | masscomp | wanginst | ci-dandelion} !ulowell!burati

<============================== Cut here ==============================>
$! Procedure LISTMAIL
$! Written:  6/85
$! By:		Michael Burati, University of Lowell CS Dept.
$!
$! Set up
$ on error then goto done
$ on severe then done
$!
$! Get a listing of what mail folders exist into mail.list
$!
$ assign mail.list sys$output
$ mail
dir/fol
$ deassign sys$output
$!
$! Parse that list, to get the individual folders
$!
$ open/read INFILE mail.list
$!
$!  Open a new file, foltmp.com which will contain the commands to
$! do directories of each folder
$!
$ open/write OUTFILE foltmp.com
$ write OUTFILE "$ MAIL"
$!
$!  Get rid of header information in mail.list
$!
$ read INFILE RECORD
$ read INFILE RECORD
$!
$!  Loop through each line of mail.list to find the folders.
$!
$ LOOP:
$   read/end_of_file=DONE INFILE RECORD
$   DONEYET = f$extract(0,1,RECORD)
$   if "''DONEYET'" .eqs. "$" then goto DONE
$   FOLDER = f$extract(0,20,RECORD)
$   write OUTFILE "select ",FOLDER
$   write OUTFILE "dir"
$   if f$len(RECORD) .le. 41 then goto loop
$   FOLDER = f$extract(40,20,RECORD)	! else get folder in right column
$   write OUTFILE "select ",FOLDER
$   write OUTFILE "dir"
$   goto loop
$!
$!  We've created foltmp.com, now lets execute it.
$!
$ DONE:
$   close INFILE
$   close OUTFILE
$   delete/nocon/nolog mail.list;*
$   assign mail.list sys$output
$!  Execute the procedure created above to list the folders.
$   @foltmp.com
$   deassign sys$output
$   delete foltmp.com;*
$!  IF '-P' was given as an arg, then print the list to lpa0:
$   if p1 .eqs. "-P" then goto LPR
$   ty/p mail.list;
$   delete mail.list;*
$   exit
$ LPR:
$   print/que=lpa0/delete mail.list;