Relay-Version: version B 2.10 5/3/83; site utzoo.UUCP
Path: utzoo!mnetor!uunet!husc6!hao!ames!sdcsvax!ucsdhub!hp-sdd!hplabs!hp-pcd!uoregon!omepd!littlei!vrs
From: vrs@littlei.UUCP (Vincent R. Slyngstad)
Newsgroups: comp.unix.xenix
Subject: Re: How to get readnews working...
Message-ID: <149@uvrs.littlei.UUCP>
Date: Thu, 3-Sep-87 18:57:02 EDT
Article-I.D.: uvrs.149
Posted: Thu Sep  3 18:57:02 1987
Date-Received: Sat, 5-Sep-87 18:07:50 EDT
References: <427@polyslo.UUCP>
Reply-To: vrs@.UUCP (Vincent R. Slyngstad)
Organization: Intel Corp., ISO Systems Development, Hillsboro, OR
Lines: 63
Keywords: news xenix rn
Summary: localize.sh for news 2.11 patch level 5

In article <427@polyslo.UUCP>, mdella@polyslo.UUCP (Marcos R. Della) writes:
> I am running an Intel 286 box (310/311 if anyone knows the peticulars) and
> have Xenix R3.4 running currently on it. I just got copies of the news
> programs (2.10.3) but cannot get them to compile correctly at all. Has
> anyone created a localize.sh for this peticular configuration (or any
> configuration close to it)? If so, could you please drop me a line at
> the bottom address (not the same as the above address)...

Here is the localize.sh that we use on the sources for our
XENIX box.  The news sources are as they were distributed
over the net with patches 1 thru 5 applied.
---------- cut here -----------
rm -f Makefile
cp Makefile.dst Makefile
chmod u+w Makefile
ed - Makefile  <<'EOF'
g/^#USG /s///
g/ #NOTVMS/s///
g/^#V7/d
g/^#BSD/d
g/^#VMS/d
/^HOME/s/exptools/news/
/^BINDIR/s;/usr/bin;/usr/local/news;
/^SCCSID/d
/^UUXFLAGS/s/ -z/ -z/
/^CFLAGS/s/-O/-Ml -O -DDBM/
.s/-Dindex.*strrchr//
/^LFLAGS/s/-s/-Ml -F 4000/
/^LIBS/s/$/ -ldbm/
/^IOBJECTS/s/\\/uname.o \\/
w
q
EOF
rm -f defs.h
cp defs.dist defs.h
chmod u+w defs.h
ed - defs.h <<'EOF'
/ROOTID/s/10/194/
/N_UMASK/s/000/002/
/NOTIFY/s/usenet/news/
/UUNAME/s/uucpname/systemid/
/DFLTSUB/s/general,all.announce/all/
/TMAIL/s;^;/*;
/PAGE/s;/usr/ucb/more;/usr/bin/more;
/DFTXMIT/s/ -z//
/UXMIT/s;^;/*;
/UUNAME/s;/\* ;;
/DOXREFS/s;/\* ;;
/HIDDENNET/s;/\* ;;
/HIDDENNET/s;frooz;littlei;
/MYORG/s=Frobozz Inc., St. Louis=/usr/lib/news/organization=
/DEADTIME/s/45/300/
$a
#define index strchr
#define rindex strrchr
.
w
q
EOF
-- 
Vincent R. Slyngstad
UNIX Evaluation Engineering
Intel Corporation (littlei!vrs)