Relay-Version: version B 2.10 5/3/83; site utzoo.UUCP
Path: utzoo!mnetor!uunet!seismo!sundc!pitstop!sun!amdcad!ames!ucbcad!ucbvax!vms.CIS.PITTSBURGH.EDU!Postmaster
From: Postmaster@vms.CIS.PITTSBURGH.EDU (PMDF Mail Server)
Newsgroups: comp.os.vms
Subject: Undeliverable mail
Message-ID: <8710290320.AA16072@ucbvax.Berkeley.EDU>
Date: Mon, 26-Oct-87 10:41:00 EST
Article-I.D.: ucbvax.8710290320.AA16072
Posted: Mon Oct 26 10:41:00 1987
Date-Received: Sat, 31-Oct-87 15:28:30 EST
Sender: daemon@ucbvax.BERKELEY.EDU
Organization: The ARPA Internet
Lines: 100

The message could not be delivered to:

Addressee: 000426
Reason: 
  %MAIL-E-NOSUCHUSR, no such user 10217_000426 at node CISVM2

----------------------------------------

Received: from JNET-DAEMON by vms.cis.pittsburgh.edu; Mon, 26 Oct 87 00:42 EDT
Received: From CMUCCVMA(MAILER) by PITTVMS with RSCS id 3827 for
 000426@PITTVMS; Mon, 26-OCT-1987 00:39 EDT
Received: by CMUCCVMA (Mailer X1.25) id 3825; Mon, 26 Oct 87 00:39:32 EST
Date: Fri, 23 Oct 87 17:05:34 EDT
From: Jim Murawski <R021JM9W@VB.CC.CMU.EDU>
Subject: Changing from daylight time to standard time
Sender: INFO-VAX Discussion <MD4I@CMUCCVMA>
To: BETH DOE <000426@vms.cis.pittsburgh.edu>
Reply-to: INFO-VAX@KL.SRI.COM
Comments: To: Info-Vax@KL.SRI.COM

     
        In most of North America, standard time starts this Sunday
        (October 25th) at 2:00.  I have whipped up a command procedure
        (that'll run in batch) to automatically change the system time
        and notify the console that the time has changed.  This same
        procedure can also be used when changing from standard time
        to daylight time.  To submit it, type:
     
        $ Submit Timechange /Parameter=("DAYLIGHT/STANDARD") -
                /After="25-Oct-1987 02:00" /[Your favorite qualifiers]
     
        In case your Vax is down at 2:00 on Sunday, the batch job will
        still set your time back by 1 hour whenever the Vax comes back up,
        so the time will still be correct.  Note that you may lose "a
        second or so" when changing the time via this procedure, but I'm
        sure most of you will find it acceptable.
                                -Jim Murawski
                                -Carnegie Mellon Computing Services
                                -Pittsburgh, PA
                                -R021JM9W@VB.CC.CMU.EDU (or CMCCVB.Bitnet)
     
$!       sys$user1:[r021jm9w]timechange.com;22
$!       Last Edit Date = Fri Oct 23 16:50:12 1987    R021JM9W
$!
$!      **  Revision History  (Start)  **
$!      ---------------------------------
$!      Fri Oct 23 16:50:12 1987 R021JM9W : Initial version.
$!      ---------------------------------
$!      **  Revision History (Finish)  **
$!
$!  TIMECHANGE - Change the time from Daylight to Standard or vice-versa,
$!               depending on the value of P1 (parameter 1 in batch).
$!
$ Save_Ver = F$Verify (1)
$ On Error Then Goto ABORT
$ On Control_Y Then Goto ABORT
$ P1 = F$Edit (P1, "UPCASE,TRIM")
$ If P1 .EQS. "STANDARD/DAYLIGHT" Then Goto START
$ If P1 .EQS. "DAYLIGHT/STANDARD" Then Goto START
$ Goto ABORT
$START:
$ Prev_Priv = F$Setprv ("OPER,LOG_IO")
$ Cur_Timestamp = F$Time ()
$ Cur_Date = F$Cvtime (Cur_Timestamp, "ABSOLUTE", "DATE")
$ Cur_Hour = F$Cvtime (Cur_Timestamp, , "HOUR")
$ Cur_Minute = F$Cvtime (Cur_Timestamp, , "MINUTE")
$ Cur_Second = F$Cvtime (Cur_Timestamp, , "SECOND")
$ Cur_Hundredth = F$Cvtime (Cur_Timestamp, , "HUNDREDTH")
$ If P1 .EQS. "STANDARD/DAYLIGHT" Then Goto ADD_HOUR
$SUB_HOUR:
$ New_Hour = F$String (F$Integer (Cur_Hour) - 1)
$ Goto NEW_TIME
$ADD_HOUR:
$ New_Hour = F$String (F$Integer (Cur_Hour) + 1)
$NEW_TIME:
$ New_Timestamp = Cur_Date + " " + New_Hour + ":" + Cur_Minute + ":" -
        + Cur_Second + "." + Cur_Hundredth
$ Set Time="''New_Timestamp'"
$ Prev_Priv = F$Setprv (Prev_Priv)
$!
$!  Notify the operator's console about the new time and send mail when OK
$!
$ Reply /Term=OPA0 /Bell -
        "Changed system time from ''Cur_Timestamp' to ''New_Timestamp'"
$ Mail /Subject="Timechange OK!!" NL: "''F$Getjpi ("", "USERNAME")'"
$ Save_Ver = F$Verify (Save_Ver)
$ Exit
$ABORT:
$ Show Symbol $Status
$ Save_Stat = $Status
$!
$!  Send mail on error and notify the operator's console
$!
$ Mail /Subject="Timechange Had Errors!!" NL: "''F$Getjpi ("", "USERNAME")'"
$ Reply /Term=OPA0 /Bell -
        "ERROR changing system time, please call ''F$Getjpi ("", "Username")'"
$ Save_Ver = F$Verify (Save_Ver)
$ Exit Save_Stat
$!
$!  End of TIMECHANGE.COM