Path: utzoo!mnetor!uunet!husc6!psuvax1!gondor!flee
From: flee@gondor.cs.psu.edu (Felix Lee)
Newsgroups: comp.unix.questions
Subject: Trapping yourself in csh.  (Fun with ignoreeof revisited)
Message-ID: <3282@psuvax1.psu.edu>
Date: 14 Feb 88 21:31:36 GMT
Sender: netnews@psuvax1.psu.edu
Reply-To: flee@gondor.cs.psu.edu (Felix Lee)
Organization: The Roadside Picnic
Lines: 46

Here's something I cobbled together one day, when I discovered that csh would
let you alias 'alias'.  It's a script you 'source' that traps you in csh.
Works on 4.[23] Berkeleyish systems.

Be prepared to:
- kill yourself from another terminal.
- disconnect your physical/telnet/rlogin connection.
- crash csh.  (I don't know any fatal csh errors)
- start up an assassin before you source this script.

Did I miss anything?
--
Felix Lee	flee@gondor.cs.psu.edu	*!psuvax1!gondor!flee

--------------------cut here--------------------
unalias *			# clear the air
unset *				#

set prompt = '(locked) /% '	# niceties
set noclobber			#

/bin/stty new eof u lnext u	# clear the terminal
/bin/stty werase '\\'		#
/bin/stty quit '\!'		#
/bin/stty rprnt "'" intr '"'	#

alias nope 'echo /-0:0": nope"'	# generic alias

set histchars = '//'		# no execution
alias exec	nope		#

alias logout	nope		# no exit
alias login	nope		#
alias exit	nope		#
alias kill	nope		#
alias suspend	nope		#
alias stop	nope		#

alias set	nope		# no repair
alias unset	nope		#
alias setenv	nope		#

alias limit	nope		# no limit

alias 'unalias'	nope		# make it final
alias 'alias'	nope		#