Path: utzoo!utgpu!water!watmath!clyde!att!osu-cis!tut.cis.ohio-state.edu!bloom-beacon!ROVER.UMD.EDU!jonnyg
From: jonnyg@ROVER.UMD.EDU (Jon Greenblatt)
Newsgroups: comp.windows.x
Subject: Xinit....
Message-ID: <8809021457.AA05377@rover.UMD.EDU>
Date: 2 Sep 88 14:57:46 GMT
Sender: daemon@bloom-beacon.MIT.EDU
Organization: The Internet
Lines: 92


	With all this talk about Xinit being so bad I thought I'd show
people what I do. First I call up X from my /etc/ttys file with the following:

ttyv0 "/usr/bin/X11/xterm -rv -display rover:0 =80x50+1+1 -fn 9x15 -sb -sl 500 -n ttyv0 -L" xterm on secure window="/usr/bin/X11/X -apa16 -x"

	The -x is a very weird get around for an IBM tty implementation
problem. Now for all the good stuff. Whell I put all my initialization in
my .login and .cshrc where they realy belong. Here they are:

[.login]
set path = ( . $home/bin /usr/ucb /bin /usr/bin /usr/bin/X11 /usr/local/bin /usr/ibm /usr/andrew/bin /usr/new)
#
# ---------- setup terminal characteristics ----------
#
if ($TERM == "xterm" && $?DISPLAY) goto noterm
echo "Please confirm (or change) your terminal type."
loop:
# This non-obvious line does the tset.
set noglob; eval `tset -e^H -s \?$TERM`
if ($TERM == "unknown") goto loop
noterm:
#
# Put some stuff here......
#
cat ~/motd
#
# Initialize xterm here if a display variable is already set and it's an
# xterm terminal.
#
if ($TERM == "xterm" && $?DISPLAY) then
	xcalc \=-25+100 &
	xphoon -t 720 &
	xset c 8
	xclock -analog \=164x164-20-20 -rv -bd white &
	xbiff \=-210-20 -rv -bw 1 -bd white &
	xload \=150x50-3+3 -rv -bw 1 -bd white &
	xterm -rv -C -n Console -sb \=60x15-5+348 -e tcsh -i -b do-console &
	uwm &
	set watch=(any any)
endif

[.cshrc]
if ($?prompt) then
#The following applies only to interactive shells, not to shell scripts
	set history = 50
	set savehist = $history # Keeps history over sessions
	set time = 2
	set ignoreeof # Don't accidentally logout
	set noclobber # Don't accidentally erase files
endif
#You may modify this as you wish
alias ls ls -F
alias rm rm -i
alias e emacs
set hostname=`hostname`
#
# I use the latest version of tcsh.
# thought this would be of interset
#
if ($?tcsh) then
  set prompt = "{%d} $USER@%m(%\!)"
else
  set prompt = "{$cwd} $USER@$hostname(\!)"
  alias cd 'chdir \!*; set prompt = "{$cwd} $USER@$hostname(\\!)"'
endif
set visual = /usr/bin/emacs
setenv VISUAL /usr/bin/emacs
if ($?TERM) then
	if ($TERM == "xterm") then
		alias xs  'set noglob; eval `resize`'
		setenv BE2WM x11
		setenv DIS $hostname\:0
	endif
endif
#
#  Set the console prompt differently.
#
if ($1 == "do-console") then
	set prompt="<console> "
endif
stty erase 


	I have xtools but I still prefer this since I would probably call
xtools from the .login anyway so why not keep everything together. The
processes seem to always behave, everything is killed on a logout or
exit from the initial xterm window.


					JonnyG.
					(jonnyg@rover.umd.edu)