Path: utzoo!utgpu!jarvis.csri.toronto.edu!cs.utexas.edu!tut.cis.ohio-state.edu!ucbvax!DHDURZ1.BITNET!K07
From: K07@DHDURZ1.BITNET (Georg Jagoda)
Newsgroups: comp.lang.asm370
Subject: Re: Macro to dump a piece of core and the registers MVS/XA
Message-ID: <8912140928.AA22939@brazos.rice.edu>
Date: 14 Dec 89 09:28:31 GMT
References: <FEATS@VTVM1>
Sender: usenet@ucbvax.BERKELEY.EDU
Reply-To: IBM 370 Assembly Programming Discussion List <ASM370%UCF1VM.BITNET@ricevm1.rice.edu>
Distribution: inet
Organization: The Internet
Lines: 54
X-Unparsable-Date: Thu, 14 Dec 89 10:11:39 CET

>Under VSE there is a macro called JDUMP which is used to dump a piece of
>core between two specified locations and dump the registers.  It is a
>handy debugger for batch assembler programs.  Now that I'm working on
>MVS/XA I have been pouring over the macro books and have not found an
>equivalent.  Can anybody point me in the right direction?
>
>Steve Greenfield
>Virginia Tech Computing Center
>Blacksburg, Virginia

Under MVS there is a macro called SNAP. I wrote a module that will dump
two areas. The two pairs of addresses are supplied by the main program:
K07SNAP  TITLE '                               K07SNAP'
K07SNAP  CSECT
         USING K07SNAP,R12
         STM   R14,R12,12(R13)    STORE CALLERS REGS
         LR    R12,R15
         LA    R2,SAVEAREA
         ST    R2,8(,R13)         PLAY THE
         ST    R13,4(,R2)          SAVEAREA GAME
         LR    R13,R2
         LA    R11,2048(R12)
         LA    R11,2048(R11)
         USING K07SNAP,R12,R11
         LR    R3,R1
         OPEN  MF=(E,OUTPUT)
         SNAP  DCB=DCB,                                                *
               LIST=(R3),                                              *
               STRHDR=STRHDR
         CLOSE (,FREE),MF=(E,OUTPUT)
         L     R13,4(,R13)        GET CALLERS SAVE AREA ADDR
         L     R14,12(,R13)       RESTORE REGS
         LM    R0,R12,20(R13)     RESTORE REGS
         BR    R14                AND RETURN
         SPACE 3
OUTPUT   OPEN  (DCB,(OUTPUT)),MF=L X'8F'
DCB      DCB   DSORG=PS,DDNAME=SYSSNAP,RECFM=VBA,MACRF=W,              *
               BLKSIZE=1632,LRECL=125
         SPACE
SAVEAREA DS    18F
STRHDR   DC    A(HDR1),X'80',AL3(HDR2)
HDR1     DC    AL1(HDR1TL)
HDR1T    DC    C'* ',6C'  XOPER  CSECT  ',C' *'
HDR1TL   EQU   *-HDR1T             MAXIMALLAENGE = 100
HDR2     DC    AL1(HDR2TL)
HDR2T    DC    C'* ',6C'  XOPER  DSECT  ',C' *'
HDR2TL   EQU   *-HDR2T             MAXIMALLAENGE = 100
         SPACE
         PRINT NOGEN
         EQUREG
         DCBD  DSORG=(PS),DEVD=(DA)
         END
Georg Jagoda, K07 at DHDURZ1 (Rechenzentrum der Universitaet Heidelberg)
Ich bin Mensch.                                 Irren bleibt menschlich.