Path: utzoo!attcan!uunet!mdcbbs!spain
From: spain@mdcbbs.com
Newsgroups: news.software.anu-news
Subject: Re: A New Topic -- Tuning News
Message-ID: <707.25e04bf4@mdcbbs.com>
Date: 19 Feb 90 19:41:40 GMT
References: <9002190935.AA25552@uunet.uu.net>
Organization: McDonnell Douglas M&E, Cypress CA
Lines: 66

> yep - and tuning the file NEWS.ITEMS is the one to concentrate on - the file is
> big and very dynamic in terms of record insertions and deletions.

I'm sure there is a more efficient method but I found that this command file
running in batch tends to find windows when it can CONVERT the news files.

$!------------------------------------------------------------------'f$verify(0)
$! Written by Harrison Spain to convert NEWS files.
$!------------------------------------------------------------------------------
$ set noon
$ say    := write sys$output
$ submit := submit
$ if f$mode() .eqs. "BATCH" then goto convert_news
$ submit /after=tomorrow /name="Convert-News" /notify -
	/nolog /que=news$batch -
	news_manager:convert_news /noprint -
	/user=system
$ exit
$convert_news:
$ submit /after=tomorrow /name="Convert-News" /notify -
	/nolog /que=news$batch -
	news_manager:convert_news /noprint -
	/user=system
$!
$ set noon
$ on error then goto wait_a_bit
$ set def uucp_disk:[uucp.news]
$!
$ n = 0
$ error_label := news_items
$news_items:
$ if n .lt. 32 then convert /reclaim /stat news.items
$ if n .ge. 32 then gosub mail_moderator
$!
$ n = 0
$ error_label := news_groups
$news_groups:
$ if n .lt. 32 then convert /reclaim /stat news.groups
$ if n .ge. 32 then gosub mail_moderator
$!
$ n = 0
$ error_label := news_history
$news_history:
$ if n .lt. 32 then convert /reclaim /stat history.v60
$ if n .ge. 32 then gosub mail_moderator
$!
$ exit
$wait_a_bit:
$ write sys$output "''error_label': ''n'"
$ n = n + 1
$ on error then goto wait_a_bit
$ wait 00:15:00
$ goto 'error_label'
$mail_moderator:
$ mail /sub="Convert of ''error_label' NEWS file failed!" sys$input moderator
Apparently it required more than 32 passes to convert one of the NEWS files.
$ return

-- 
  =============================================================
 | Harrison M. Spain III |    Voice: (714) 952-6114            |
 | Sr. Section Manager   |      Fax: (714) 952-5371            |
 | McDonnell Douglas M&E | Internet: spain@mdcbbs.com          |
 | 5701 Katella Ave.     |     UUCP: uunet!mdcbbs.com!spain    |
 | Cypress, CA  90630    |      PSI: PSI%31060099980019::SPAIN |
  =============================================================